Pinkbyte/pinkbyte-overlay
1
Fork 0
Code Releases Activity

simply bump version of all compiz-related ebuilds

Browse Source
This commit is contained in:
Sergey Popov 2012-02-19 17:00:42 +04:00
parent bc24afc776
commit 890e1a3238
19 changed files with 528 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

2
x11-libs/compiz-bcop/Manifest
View File

@ -1,2 +1,4 @@
DIST compiz-bcop-0.8.4.tar.bz2 72103 RMD160 7e29398ef0ad211c9eccb0fd6deae68a00285e70 SHA1 c9632cd9d27f9335f1282fca2a4aa87b2fc4668d SHA256 d359ca1a9e98e0a4b9abe807f84a9e230a102aee409f3ee4594a895ea9da8c4f
DIST compiz-bcop-0.8.8.tar.bz2 75886 RMD160 429d9a2bd324d3decd8a7a393f915401d287fcb7 SHA1 9210bd2a537480bdb11df0e3cc5f6d4548fd12da SHA256 0c6eb97f47012c2d621953962df8bf9338d535c546bf2e8088860ba574efb436
EBUILD compiz-bcop-0.8.4-r9999.ebuild 585 RMD160 5e0397555008056c3332ad00867c76ef30b85735 SHA1 b55be421308b687507963b945d5fc36f1ec04b31 SHA256 91e60ed41f619430332289a288f2c42574c64de365b1d5628e500dcd6fd05f14
EBUILD compiz-bcop-0.8.8-r9999.ebuild 585 RMD160 5e0397555008056c3332ad00867c76ef30b85735 SHA1 b55be421308b687507963b945d5fc36f1ec04b31 SHA256 91e60ed41f619430332289a288f2c42574c64de365b1d5628e500dcd6fd05f14

20
x11-libs/compiz-bcop/compiz-bcop-0.8.8-r9999.ebuild Normal file
View File

@ -0,0 +1,20 @@
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/compiz-bcop/compiz-bcop-0.8.4.ebuild,v 1.1 2009/10/15 16:35:51 mrpouet Exp $
DESCRIPTION="Compiz Option code Generator"
HOMEPAGE="http://www.compiz.org/"
SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE=""
RDEPEND="dev-libs/libxslt"
DEPEND="${RDEPEND}
>=dev-util/pkgconfig-0.19"
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
}

2
x11-libs/compizconfig-backend-kconfig4/Manifest
View File

@ -1,2 +1,4 @@
DIST compizconfig-backend-kconfig4-0.8.4.tar.bz2 21680 RMD160 a81152111a4c61dd27e6b749071433a833579dcf SHA1 3a9146e68a93ee40db87b791d03c4225dcd03507 SHA256 73916cc47977a82dde8c619892841db8a53b2b0f1c2d99bee60b71afdb4795ea
DIST compizconfig-backend-kconfig4-0.8.8.tar.bz2 21632 RMD160 1278bae563027d4be3bc6f3c5470c667a52163e8 SHA1 d7a29339b47233ad53fe04ca0136fdb511b945ac SHA256 90c3a4a0fdcbee21479dd56685bb101f9a5f70a57c953dfb4fa372e99fceb767
EBUILD compizconfig-backend-kconfig4-0.8.4-r9999.ebuild 586 RMD160 51cb520f0fc79f8456650141e3e20eb2ea31a51a SHA1 ac587b7ac951f75261ea71f30e9de173b1367d3a SHA256 86718e3fcb65bc9c3bc4749c59bfa0073d72a54d6c089811e4e2e42d00a86972
EBUILD compizconfig-backend-kconfig4-0.8.8-r9999.ebuild 586 RMD160 51cb520f0fc79f8456650141e3e20eb2ea31a51a SHA1 ac587b7ac951f75261ea71f30e9de173b1367d3a SHA256 86718e3fcb65bc9c3bc4749c59bfa0073d72a54d6c089811e4e2e42d00a86972

20
x11-libs/compizconfig-backend-kconfig4/compizconfig-backend-kconfig4-0.8.8-r9999.ebuild Normal file
View File

@ -0,0 +1,20 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/compizconfig-backend-kconfig4/compizconfig-backend-kconfig4-0.8.4.ebuild,v 1.4 2011/10/28 20:53:01 abcd Exp $
EAPI=4
inherit kde4-base
DESCRIPTION="Compizconfig Kconfig Backend"
HOMEPAGE="http://www.compiz.org/"
SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.bz2"
LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE=""
DEPEND="x11-libs/qt-dbus:4
>=x11-libs/libcompizconfig-${PV}
>=x11-wm/compiz-${PV}"

2
x11-libs/libcompizconfig/Manifest
View File

@ -1,4 +1,6 @@
AUX libcompizconfig-0.8.2-allow-system-libiniparser.patch 6993 RMD160 cbbc8b04653a1175ce299d63974d22ca739f4cab SHA1 678634c48f8543ee26c54ec9a404b619657257e3 SHA256 4a6511605a6d6a6a45b528a344e2a79fd9e5b98cd8bbc0a94c3257fec44cce76
AUX libcompizconfig-undefinedref.patch 1204 RMD160 69538e32c526828d1e3d0ae6116f7b62a207edba SHA1 c97312c81ac6ac445d56599c10cf67418f0bd9db SHA256 27c3a644ea5b0b309ec32ed79f4a51f81ec2bc20cc9ccc73525237785052581d
DIST libcompizconfig-0.8.4.tar.bz2 315858 RMD160 dee403af09eee727717aeee82f763dfdb4ba3cd9 SHA1 514830508b21f9fd47ccac128c44c55a212d3929 SHA256 41313e935f1beb3375367bded72d97de60e7aabf1129620be53a7fc1aca0b029
DIST libcompizconfig-0.8.8.tar.bz2 318176 RMD160 bdd9f26d092c6eccfd651ea2735d1544311d731f SHA1 8ea1f15fd9e1e2eb37a9814646659a31a8018fd8 SHA256 50a81aba31d9517587f7d046b7161eb4204ddceb422d09d036a412bb80381490
EBUILD libcompizconfig-0.8.4-r9999.ebuild 847 RMD160 12d37ebe086f2974953713de348639f33271733a SHA1 c8db45ac7597089d190e1d747e3e120b16fd21d9 SHA256 d21a1b7cb72be1783cec39c873991d70a270c871e06303feb3c013d31003da27
EBUILD libcompizconfig-0.8.8-r9999.ebuild 847 RMD160 12d37ebe086f2974953713de348639f33271733a SHA1 c8db45ac7597089d190e1d747e3e120b16fd21d9 SHA256 d21a1b7cb72be1783cec39c873991d70a270c871e06303feb3c013d31003da27

38
x11-libs/libcompizconfig/libcompizconfig-0.8.8-r9999.ebuild Normal file
View File

@ -0,0 +1,38 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/libcompizconfig/libcompizconfig-0.8.4-r2.ebuild,v 1.2 2011/03/21 19:52:57 nirbheek Exp $
EAPI="2"
DESCRIPTION="Compiz Configuration System"
HOMEPAGE="http://www.compiz.org/"
SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE=""
RDEPEND="
dev-libs/libxml2:2
dev-libs/protobuf
>=x11-wm/compiz-${PV}
"
DEPEND="${RDEPEND}
>=dev-util/intltool-0.41
>=dev-util/pkgconfig-0.19
"
RESTRICT="test"
src_configure() {
econf \
--disable-dependency-tracking \
--enable-fast-install \
--disable-static
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
find "${D}" -name '*.la' -delete || die
}

2
x11-plugins/compiz-plugins-extra/Manifest
View File

@ -1,4 +1,6 @@
AUX compiz-plugins-extra-0.8.6-libnotify.patch 1412 RMD160 a4e1a09e293c5e1a16bf3b0fd7710d7440c12bcc SHA1 c9201df9851f3ef325fe6b2f612097bc10723b1b SHA256 864971c7f1ad664d64c4cfcca527c2a9788f95a2b030b2cc94f1d2ad9332c106
AUX compiz-plugins-extra-no-gconf.patch 585 RMD160 bb3b291eab783be7f9754d724d3a96618fe2e614 SHA1 564d6614cc157397ae24347a731a9f4d65bf30f8 SHA256 0567850b07c3973f1b4bfd5c36a1e240a57e45a1714b63637ecec577febfc13f
DIST compiz-plugins-extra-0.8.6.tar.bz2 2699385 RMD160 cd8d26902d38ee7fb42fe2077e483f92fc458929 SHA1 66c571c64910aa21808aedaee8c8ceb4c4a82c78 SHA256 e111beecd9e563065448aae81002fd6cb644b3cd0e11a8406d6a2d3146747de1
DIST compiz-plugins-extra-0.8.8.tar.bz2 2689953 RMD160 948fc491075f202759a31a3395fcd31deb6fa101 SHA1 ce592993696c0b5d4e0bb13171897b4c25b3844e SHA256 bdce203098c62370b01b87741b04d3d9bc37e918789acce07120c4f081d5bbe3
EBUILD compiz-plugins-extra-0.8.6-r9999.ebuild 1564 RMD160 28cf176862dd4bb9cfee9b434ab691090e9490f0 SHA1 ffedde3e900095a8b784856285f07937006da03a SHA256 59504a217dcdbbe674c9f21932d9a1a1e3b7981b5c1f0ebce02240196f89256a
EBUILD compiz-plugins-extra-0.8.8-r9999.ebuild 1614 RMD160 9e1f235af93ba19013d02cb5c7e9b82ea4b37585 SHA1 dcbdb7c1dd7176215dd78e2e8927982ec19c4925 SHA256 73415cab9299d73fc82b48b0468ecd350b4a850e964a2610483f29fb30972826

70
x11-plugins/compiz-plugins-extra/compiz-plugins-extra-0.8.8-r9999.ebuild Normal file
View File

@ -0,0 +1,70 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-plugins/compiz-plugins-extra/compiz-plugins-extra-0.8.6-r1.ebuild,v 1.5 2011/03/21 19:47:45 nirbheek Exp $
EAPI="2"
inherit autotools eutils gnome2-utils
DESCRIPTION="Compiz Fusion Window Decorator Extra Plugins"
HOMEPAGE="http://www.compiz.org/"
SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="gconf libnotify"
MY_PV="0.8.4"
RDEPEND="
>=gnome-base/librsvg-2.14.0:2
virtual/jpeg:0
>=x11-libs/compiz-bcop-${MY_PV}
>=x11-plugins/compiz-plugins-main-${PV}
>=x11-wm/compiz-${PV}[gconf?]
libnotify? ( x11-libs/libnotify )
"
DEPEND="${RDEPEND}
>=dev-util/intltool-0.35
>=dev-util/pkgconfig-0.19
>=sys-devel/gettext-0.15
x11-libs/cairo
gconf? ( gnome-base/gconf:2 )
"
src_prepare() {
if ! use gconf; then
epatch "${FILESDIR}"/${PN}-no-gconf.patch
fi
# Pinkbyte: !STUB! Need to adapt patch for 0.8.8
# epatch "${FILESDIR}/${P}-libnotify.patch"
# required to apply the above patch
intltoolize --copy --force || die "intltoolize failed"
eautoreconf || die "eautoreconf failed"
}
src_configure() {
econf \
--disable-dependency-tracking \
--enable-fast-install \
--disable-static \
$(use_enable gconf schemas) \
$(use_with libnotify)
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
find "${D}" -name '*.la' -delete || die
}
pkg_preinst() {
use gconf && gnome2_gconf_savelist
}
pkg_postinst() {
use gconf && gnome2_gconf_install
}

2
x11-plugins/compiz-plugins-main/Manifest
View File

@ -1,4 +1,6 @@
AUX compiz-plugins-main-0.8.4-put-plugin.patch 6918 RMD160 1c14b58a95694e711d1dcd0036471fe465cf2a0e SHA1 fc50491bc22fe1f46f2779b9e24fc07e4c15bdc4 SHA256 1155ac5765d1712b8dee5813b41a638ea01cc16519837e7137a69d6a1e79e614
AUX compiz-plugins-main-no-gconf.patch 586 RMD160 1222325cbec30e35030c930cd3a9358a3b975047 SHA1 95ef3484e60b4f3c4d0bced6b0fb654e7cbcff89 SHA256 bc13b648e2198dd3611ba4f4734540903a740570a2c181dc666dd1e66f13e1da
DIST compiz-plugins-main-0.8.6.tar.bz2 1226802 RMD160 7eefc691c26199487309fc5e5b0993bfe3f3dd86 SHA1 6cd9c6a48c570061ac0b6275a6acddd8415b8611 SHA256 66dc4f349b11dbeac08f941d2d3443aa9b80d82f35c304db747ff383491ed6d9
DIST compiz-plugins-main-0.8.8.tar.bz2 1230627 RMD160 b6835f95d2f5e3e46bf36fe4e5347b08debcda19 SHA1 3c99841b744ae6c4a3edf2019626484880607dc6 SHA256 c79278b5369660d6274661a2c196f1cb016ef2b5d34e30bd18dbaeb241bee248
EBUILD compiz-plugins-main-0.8.6-r9999.ebuild 1403 RMD160 f080d6b5f7b678ef28cbc4e00369f292f9d89bc3 SHA1 d87a87334f3c0c25e5a798ab72b20e1052683c36 SHA256 7aa45b32b82a440595bd9ad9ec8cb65b7402fed4bfc18428d46dc3fb8c1961c8
EBUILD compiz-plugins-main-0.8.8-r9999.ebuild 1403 RMD160 f080d6b5f7b678ef28cbc4e00369f292f9d89bc3 SHA1 d87a87334f3c0c25e5a798ab72b20e1052683c36 SHA256 7aa45b32b82a440595bd9ad9ec8cb65b7402fed4bfc18428d46dc3fb8c1961c8

64
x11-plugins/compiz-plugins-main/compiz-plugins-main-0.8.8-r9999.ebuild Normal file
View File

@ -0,0 +1,64 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-plugins/compiz-plugins-main/compiz-plugins-main-0.8.6-r1.ebuild,v 1.4 2011/03/21 19:50:33 nirbheek Exp $
EAPI="2"
inherit autotools eutils gnome2-utils
DESCRIPTION="Compiz Fusion Window Decorator Plugins"
HOMEPAGE="http://www.compiz.org/"
SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="gconf"
MY_PV="0.8.4"
RDEPEND="
>=gnome-base/librsvg-2.14.0:2
virtual/jpeg:0
x11-libs/cairo
>=x11-libs/compiz-bcop-${MY_PV}
>=x11-wm/compiz-${PV}[gconf?]
"
DEPEND="${RDEPEND}
>=dev-util/intltool-0.35
>=dev-util/pkgconfig-0.19
>=sys-devel/gettext-0.15
gconf? ( gnome-base/gconf:2 )
"
src_prepare() {
if ! use gconf; then
epatch "${FILESDIR}"/${PN}-no-gconf.patch
# required to apply the above patch
intltoolize --copy --force || die "intltoolize failed"
eautoreconf || die "eautoreconf failed"
fi
}
src_configure() {
econf \
--disable-dependency-tracking \
--enable-fast-install \
--disable-static \
$(use_enable gconf schemas)
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
find "${D}" -name '*.la' -delete || die
}
pkg_preinst() {
use gconf && gnome2_gconf_savelist
}
pkg_postinst() {
use gconf && gnome2_gconf_install
}

2
x11-plugins/compiz-plugins-unsupported/Manifest
View File

@ -1,2 +1,4 @@
DIST compiz-plugins-unsupported-0.8.4.tar.bz2 1152247 RMD160 349aad141ae02ab024b88ee61649478c364862a4 SHA1 8c322e06bd6d7f84f3b7cd9b28034333a3ad2793 SHA256 50b6aec773e72d5c0e2de801b83d323feb17d2399cc632a49d6641c888dd1006
DIST compiz-plugins-unsupported-0.8.8.tar.bz2 1155793 RMD160 d5aa9550ca8fadf3c968f5f9820b66b111b990bc SHA1 e3d47d2c5bb61b57b859c3541453136046f4e80a SHA256 0b2ed265eda34dd60e1155280cb944bef07499f5f8178fc2498c243b2809481e
EBUILD compiz-plugins-unsupported-0.8.4-r9999.ebuild 869 RMD160 728263ad82309c682dcc0bf346764b5bfa403c11 SHA1 006140e282292cea3e0590d57aedc777317757a4 SHA256 e5f0823eb5f8945cadca6eb3945d93221a53f4992d264a6e6ae40026b8e360ec
EBUILD compiz-plugins-unsupported-0.8.8-r9999.ebuild 869 RMD160 728263ad82309c682dcc0bf346764b5bfa403c11 SHA1 006140e282292cea3e0590d57aedc777317757a4 SHA256 e5f0823eb5f8945cadca6eb3945d93221a53f4992d264a6e6ae40026b8e360ec

35
x11-plugins/compiz-plugins-unsupported/compiz-plugins-unsupported-0.8.8-r9999.ebuild Normal file
View File

@ -0,0 +1,35 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-plugins/compiz-plugins-unsupported/compiz-plugins-unsupported-0.8.4-r1.ebuild,v 1.3 2011/03/21 19:51:02 nirbheek Exp $
EAPI="2"
DESCRIPTION="Compiz Fusion Window Decorator Unsupported Plugins"
HOMEPAGE="http://www.compiz.org/"
SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE=""
RDEPEND="
>=gnome-base/librsvg-2.14.0:2
virtual/jpeg:0
>=x11-libs/compiz-bcop-${PV}
>=x11-plugins/compiz-plugins-main-${PV}
>=x11-wm/compiz-${PV}
"
DEPEND="${RDEPEND}
>=dev-util/intltool-0.35
>=dev-util/pkgconfig-0.19
>=sys-devel/gettext-0.15
x11-libs/cairo
"
RESTRICT="mirror"
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
}

1
x11-wm/compiz-fusion/Manifest
View File

@ -1 +1,2 @@
EBUILD compiz-fusion-0.8.6-r9999.ebuild 949 RMD160 4add77884ee9a1748380fea43a006e65673dce92 SHA1 010a6adc9efc137416183da723bb940787605cd9 SHA256 5c6efe9ec0ac7a25371bd2b7bc244a572749f5938bbfa2de37c718b5e5d7179b
EBUILD compiz-fusion-0.8.8-r9999.ebuild 949 RMD160 4add77884ee9a1748380fea43a006e65673dce92 SHA1 010a6adc9efc137416183da723bb940787605cd9 SHA256 5c6efe9ec0ac7a25371bd2b7bc244a572749f5938bbfa2de37c718b5e5d7179b

29
x11-wm/compiz-fusion/compiz-fusion-0.8.8-r9999.ebuild Normal file
View File

@ -0,0 +1,29 @@
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz-fusion/compiz-fusion-0.8.6.ebuild,v 1.1 2010/04/03 06:13:26 jmbsvicetto Exp $
DESCRIPTION="Compiz Fusion (meta)"
HOMEPAGE="http://www.compiz.org/"
SRC_URI=""
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="emerald gnome kde unsupported"
MY_PV=0.8.4
RDEPEND="
>=x11-wm/compiz-${PV}
>=x11-plugins/compiz-plugins-main-${PV}
>=x11-plugins/compiz-plugins-extra-${PV}
unsupported? ( >=x11-plugins/compiz-plugins-unsupported-${MY_PV} )
>=x11-apps/ccsm-${MY_PV}
emerald? ( >=x11-wm/emerald-${MY_PV} )
gnome? ( >=x11-libs/compizconfig-backend-gconf-${MY_PV} )
kde? ( >=x11-libs/compizconfig-backend-kconfig4-${MY_PV} )"
pkg_postinst() {
ewarn "If you want to try out simple-ccsm, you'll need to emerge it"
ewarn "If you want to use emerald, set the emerald use flag"
}

2
x11-wm/compiz/Manifest
View File

@ -14,4 +14,6 @@ AUX compiz-manager 9835 RMD160 0c579ebd41c22b4f33edb2d2d5b1e41ac30720ac SHA1 ff3
AUX compiz-no-gconf.patch 630 RMD160 32b6990dff7baf7f3cb04f728ab04d1523f29c46 SHA1 ad1c0a38dcb83c4768031f0b87db4748b2c24b92 SHA256 87467fbe5d4e0d0bb8952f2d5b74d21046d92d49772543aeda137266e055aa67
AUX compiz.desktop 273 RMD160 704f0e631cd41d810af323b5fabbbf7eac5a943b SHA1 e244587cc28613ab92568846754e91bb193f0e85 SHA256 28a5459148c7733cdd82e3ecc1f584231d2619c7305b8bf71060db331bf081fb
DIST compiz-0.8.6.tar.bz2 1162334 RMD160 7a5476a21143e29ac2e35465c49e8a52b629a864 SHA1 8d5998cb18418283cbd367f126a65dde4062ad00 SHA256 c4df69b59b5660a37462de9ff0212af024ccf9c8038651bfda3557c955ab4f8c
DIST compiz-0.8.8.tar.bz2 1123892 RMD160 430e6ce18e2fc7f6b95907dbc089ec26c2629773 SHA1 ca86f8586f921f084d32c2548a5d2170179a5caf SHA256 3ba555b0d6d536850a227d37d6ebc5cd5b15ee5bad83d7956529a27b870977e3
EBUILD compiz-0.8.6-r9999.ebuild 4035 RMD160 794d59ba44892aca9d335e4c2d70184a8925b90a SHA1 1ab759f6767873cdee8bacddd483e59b9e8d1c8f SHA256 e5d7add1f1bff6a09baf3e68376dd9f59b5762b83241d439823cd0604db56dce
EBUILD compiz-0.8.8-r9999.ebuild 4037 RMD160 1f8a7cc4e54333d5d99f692546c22653933faedc SHA1 aa53558f0b0cd234ae2bd5de76cb5ff624558532 SHA256 c85518541132bec6a5fb239270bec30180559d397331dfd14285ebc4c4ccf77c

168
x11-wm/compiz/compiz-0.8.8-r9999.ebuild Normal file
View File

@ -0,0 +1,168 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/compiz-0.8.6-r3.ebuild,v 1.3 2011/11/11 22:54:51 ssuominen Exp $
EAPI="2"
inherit autotools eutils gnome2-utils
DESCRIPTION="OpenGL window and compositing manager"
HOMEPAGE="http://www.compiz.org/"
SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.bz2"
LICENSE="GPL-2 LGPL-2.1 MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
# dbus has been disabled because of bug 365121
IUSE="+cairo fuse gnome gconf gtk kde +svg" # dbus
COMMONDEPEND="
dev-libs/glib:2
dev-libs/libxml2:2
dev-libs/libxslt
media-libs/libpng
>=media-libs/mesa-6.5.1-r1
>=x11-base/xorg-server-1.1.1-r1
>=x11-libs/libX11-1.4
x11-libs/libxcb
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXinerama
x11-libs/libXrandr
x11-libs/libICE
x11-libs/libSM
>=x11-libs/libXrender-0.8.4
>=x11-libs/startup-notification-0.7
cairo? (
x11-libs/cairo[X]
)
fuse? ( sys-fs/fuse )
gnome? (
>=gnome-base/gnome-control-center-2.16.1:2
gnome-base/gnome-desktop:2
gconf? ( gnome-base/gconf:2 )
)
gtk? (
>=x11-libs/gtk+-2.8.0:2
>=x11-libs/libwnck-2.18.3:1
x11-libs/pango
)
kde? (
|| (
>=kde-base/kwin-4.2.0
kde-base/kwin:live
)
)
svg? (
>=gnome-base/librsvg-2.14.0:2
>=x11-libs/cairo-1.0
)
"
# dbus? ( >=sys-apps/dbus-1.0 )
DEPEND="${COMMONDEPEND}
dev-util/pkgconfig
x11-proto/damageproto
x11-proto/xineramaproto
"
RDEPEND="${COMMONDEPEND}
x11-apps/mesa-progs
x11-apps/xvinfo
"
src_prepare() {
echo "gtk/gnome/compiz-wm.desktop.in" >> "${S}/po/POTFILES.skip"
echo "metadata/core.xml.in" >> "${S}/po/POTFILES.skip"
# fix cont corruption, bug #343861
# epatch "${FILESDIR}"/${P}-r2-fontcorruption.patch
# epatch "${FILESDIR}"/${P}-gdk-display-deprecated.patch
if ! use gnome || ! use gconf; then
epatch "${FILESDIR}"/${PN}-no-gconf.patch
fi
eautoreconf
}
src_configure() {
local myconf=
# We make gconf optional by itself, but only if gnome is also
# enabled, otherwise we simply disable it.
if use gnome; then
myconf="${myconf} $(use_enable gconf)"
else
myconf="${myconf} --disable-gconf"
fi
econf \
--disable-dependency-tracking \
--enable-fast-install \
--disable-static \
--disable-gnome-keybindings \
--with-default-plugins \
$(use_enable svg librsvg) \
$(use_enable cairo annotate) \
--disable-dbus \
--disable-dbus-glib \
$(use_enable fuse) \
$(use_enable gnome) \
$(use_enable gnome metacity) \
$(use_enable gtk) \
$(use_enable kde kde4) \
--disable-kde \
${myconf}
# $(use_enable dbus)
# $(use_enable dbus dbus-glib)
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
find "${D}" -name '*.la' -delete || die
# Install compiz-manager
dobin "${FILESDIR}/compiz-manager" || die "dobin failed"
# Add the full-path to lspci
sed -i "s#lspci#/usr/sbin/lspci#" "${D}/usr/bin/compiz-manager" || die "sed 1 failed"
# Fix the hardcoded lib paths
sed -i "s#/lib/#/$(get_libdir)/#g" "${D}/usr/bin/compiz-manager" || die "sed 2 failed"
# Create gentoo's config file
dodir /etc/xdg/compiz || die "dodir failed"
cat <<- EOF > "${D}/etc/xdg/compiz/compiz-manager"
COMPIZ_BIN_PATH="/usr/bin/"
PLUGIN_PATH="/usr/$(get_libdir)/compiz/"
LIBGL_NVIDIA="/usr/$(get_libdir)/opengl/xorg-x11/lib/libGL.so.1.2"
LIBGL_FGLRX="/usr/$(get_libdir)/opengl/xorg-x11/lib/libGL.so.1.2"
KWIN="$(type -p kwin)"
METACITY="$(type -p metacity)"
SKIP_CHECKS="yes"
EOF
dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"
insinto "/usr/share/applications"
doins "${FILESDIR}/compiz.desktop" || die "Failed to install compiz.desktop"
}
pkg_preinst() {
use gnome && use gconf && gnome2_gconf_savelist
}
pkg_postinst() {
use gnome && use gconf && gnome2_gconf_install
ewarn "If you update to x11-wm/metacity-2.24 after you install ${P},"
ewarn "gtk-window-decorator will crash until you reinstall ${PN} again."
}
pkg_prerm() {
use gnome && gnome2_gconf_uninstall
}

3
x11-wm/emerald/Manifest
View File

@ -1,4 +1,7 @@
AUX emerald-0.8.4-gtk+-2.20-build.patch 1194 RMD160 f87d90db0341b77937b1c32521752bf0420974f8 SHA1 849f7aadb60dc702260e9900330cd5bc2a5a3242 SHA256 c196b2720ffa2996992e02b62d02f67c0f7f9dd7301fc6ceb26a1b1c81d5bcec
AUX emerald-0.8.4-pkgconfig-pollution.patch 353 RMD160 bf3505f23e43b853524f0a12016a8b06762e7420 SHA1 7efec914dfe6b8bfe53386ce5d96d58a95eab9c7 SHA256 bd4540b8ed94d5b7ba747a0285244564bae9d84cdba7a0fda3e2962d57e82224
AUX emerald-0.8.8-pkgconfig-pollution.patch 353 RMD160 bf3505f23e43b853524f0a12016a8b06762e7420 SHA1 7efec914dfe6b8bfe53386ce5d96d58a95eab9c7 SHA256 bd4540b8ed94d5b7ba747a0285244564bae9d84cdba7a0fda3e2962d57e82224
DIST emerald-0.8.4.tar.bz2 525316 RMD160 de04228414419141c3df0e7f32a062cc6dfabcda SHA1 408bef6ba7822bd933448f16dc43bbd3d801d9c9 SHA256 7ed5009a739219c61c26176f738ba5264e93557f353fdf9fc480c73fe8b05e26
DIST emerald-0.8.8.tar.bz2 528715 RMD160 a7c7a04f5ef3edb7816a693204872a1274ccab11 SHA1 a5deb2ae135d1c4dac7b57b2a0415f320ae7c0aa SHA256 239285ced20e817f5303e935d922236f828ca905b264833005a330df2089e8a3
EBUILD emerald-0.8.4-r9999.ebuild 1322 RMD160 f718ced3d777ca6b3231b0edb4d1ff096fc645cc SHA1 16273fa1655d00c00913c89c4e3bf262821d4a9c SHA256 a20184ca2c985845718f2269da5ffd577ed8b18310dd885e19e201cdf6aadd79
EBUILD emerald-0.8.8-r9999.ebuild 1238 RMD160 65948c9a5e6602f4a10ecd04a029ad5f0ed64790 SHA1 271a49199097b144222879b803374cec1bafb3ad SHA256 3ed9629c2b0d82dd961f45917c886245db9e5bf303205fcc7d23625d9484ee56

54
x11-wm/emerald/emerald-0.8.8-r9999.ebuild Normal file
View File

@ -0,0 +1,54 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/emerald/emerald-0.8.4-r2.ebuild,v 1.4 2011/09/14 20:47:24 ssuominen Exp $
EAPI="2"
inherit eutils
THEMES_RELEASE=0.5.2
DESCRIPTION="Emerald Window Decorator"
HOMEPAGE="http://www.compiz.org/"
SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE=""
PDEPEND="~x11-themes/emerald-themes-${THEMES_RELEASE}"
RDEPEND="
>=x11-libs/gtk+-2.8.0:2
>=x11-libs/libwnck-2.14.2:1
>=x11-wm/compiz-${PV}
"
DEPEND="${RDEPEND}
>=dev-util/intltool-0.35
>=dev-util/pkgconfig-0.19
>=sys-devel/gettext-0.15
"
src_prepare() {
# Fix pkg-config file pollution wrt #380197
epatch "${FILESDIR}"/${P}-pkgconfig-pollution.patch
# fix build with gtk+-2.22 - bug 341143
sed -i -e '/#define G[DT]K_DISABLE_DEPRECATED/s:^://:' \
include/emerald.h || die
}
src_configure() {
econf \
--disable-dependency-tracking \
--disable-static \
--enable-fast-install \
--disable-mime-update || die "econf failed"
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
find "${D}" -name '*.la' -delete || die
}

12
x11-wm/emerald/files/emerald-0.8.8-pkgconfig-pollution.patch Normal file
View File

@ -0,0 +1,12 @@
--- libengine/emeraldengine.pc.in
+++ libengine/emeraldengine.pc.in
@@ -7,6 +7,7 @@
Description: Library for Emerald Engines
Version: @VERSION@
-Requires: @EMERALD_REQUIRES@
-Libs: @EMERALD_LIBS@
+Requires.private: @EMERALD_REQUIRES@
+Libs: -L${libdir} -lemeraldengine
+Libs.private: @EMERALD_LIBS@
Cflags: @EMERALD_CFLAGS@ -I${includedir}/emerald